- Table of contents
- Important Note
- Why do we need this AsyncWebServer_ESP32_W6100 library
- Changelog
- Prerequisites
- Installation
- Important things to remember
- Principles of operation
- Request Variables
- Responses
- Redirect to another URL
- Basic response with HTTP Code
- Basic response with HTTP Code and extra headers
- Basic response with string content
- Basic response with string content and extra headers
- Respond with content coming from a Stream
- Respond with content coming from a Stream and extra headers
- Respond with content coming from a Stream containing templates
- Respond with content coming from a Stream containing templates and extra headers
- Respond with content using a callback
- Respond with content using a callback and extra headers
- Respond with content using a callback containing templates
- Respond with content using a callback containing templates and extra headers
- Chunked Response
- Chunked Response containing templates
- Print to response
- ArduinoJson Basic Response
- ArduinoJson Advanced Response
- Param Rewrite With Matching
- Using filters
- Bad Responses
- Async WebSocket Plugin
- Async Event Source Plugin
- Remove handlers and rewrites
- Setting up the server
- How to connect W6100 to ESP32
- Examples
- 1. Async_AdvancedWebServer
- 2. Async_AdvancedWebServer_MemoryIssues_SendArduinoString
- 3. Async_AdvancedWebServer_MemoryIssues_Send_CString
- 4. Async_AdvancedWebServer_SendChunked
- 5. Async_HelloServer
- 6. Async_HelloServer2
- 7. Async_HttpBasicAuth
- 8. AsyncMultiWebServer_ESP32_W6100
- 9. Async_PostServer
- 10. Async_RegexPatterns_ESP32_W6100
- 11. AsyncSimpleServer_ESP32_W6100
- 12. AsyncWebServer_SendChunked
- 13. Async_WebSocketsServer
- 14. MQTTClient_Auth
- 15. MQTTClient_Basic
- 16. MQTT_ThingStream
- Example Async_AdvancedWebServer
- Debug Terminal Output Samples
- 1. AsyncMultiWebServer_ESP32_W6100 on ESP32_DEV with ESP32_W6100
- 2. Async_AdvancedWebServer_MemoryIssues_Send_CString on ESP32_DEV with ESP32_W6100
- 3. Async_AdvancedWebServer_SendChunked on ESP32_DEV with ESP32_W6100
- 4. AsyncWebServer_SendChunked on ESP32_DEV with ESP32_W6100
- 5. Async_WebSocketsServer on ESP32_DEV with ESP32_W6100
- 6. Async_HTTPBasicAuth on ESP32_DEV with ESP32_W6100
- Debug
- Troubleshooting
- Issues
- TO DO
- DONE
- Contributions and Thanks
- Contributing
- License
- Copyright
The library has a new and powerful feature to permit using CString to save heap to send very large data.
Check the marvelleous PRs of @salasidis in Portenta_H7_AsyncWebServer library
- request->send(200, textPlainStr, jsonChartDataCharStr); - Without using String Class - to save heap #8
- All memmove() removed - string no longer destroyed #11
and these new examples
- Async_AdvancedWebServer_MemoryIssues_Send_CString
- Async_AdvancedWebServer_MemoryIssues_SendArduinoString
If using Arduino String, to send a buffer around 30 KBytes, the used Max Heap is around 143,424 bytes
If using CString in regular memory, with the same 30 KBytes, the used Max Heap is around 113,392 bytes, saving around a buffer size (30 KBytes)
This is very critical in use-cases where sending very large data is necessary, without heap-allocation-error.
- The traditional function used to send
Arduino Stringis
void send(int code, const String& contentType = String(), const String& content = String());such as
request->send(200, textPlainStr, ArduinoStr);The required additional HEAP is about 3 times of the String size
- To use
CStringwith copying while sending. Use function
void send(int code, const String& contentType, const char *content, bool nonDetructiveSend = true); // RSMODsuch as
request->send(200, textPlainStr, cStr);The required additional HEAP is also about 2 times of the CString size because of unnecessary copies of the CString in HEAP. Avoid this unefficient way.
- To use
CStringwithout copying while sending. Use function
void send(int code, const String& contentType, const char *content, bool nonDetructiveSend = true); // RSMODsuch as
request->send(200, textPlainStr, cStr, false);The required additional HEAP is about 1 times of the CString size. This way is the best and most efficient way to use by avoiding of unnecessary copies of the CString in HEAP
Why do we need this AsyncWebServer_ESP32_W6100 library
This library is based on, modified from:
to apply the better and faster asynchronous feature of the powerful ESPAsyncWebServer Library into (ESP32 + W6100).
- Using asynchronous network means that you can handle more than one connection at the same time
- You are called once the request is ready and parsed
- When you send the response, you are immediately ready to handle other connections while the server is taking care of sending the response in the background
- Speed is OMG
- Easy to use API, HTTP Basic and Digest MD5 Authentication (default), ChunkedResponse
- Easily extensible to handle any type of content
- Supports Continue 100
- Async WebSocket plugin offering different locations without extra servers or ports
- Async EventSource (Server-Sent Events) plugin to send events to the browser
- URL Rewrite plugin for conditional and permanent url rewrites
- ServeStatic plugin that supports cache, Last-Modified, default index and more
- Simple template processing engine to handle templates
- (ESP32 + W6100 Ethernet) boards
Arduino IDE 1.8.19+for Arduino.ESP32 Core 2.0.6+for ESP32-based boards. ESP32 Latest CoreAsyncTCP library v1.1.1+. To install manually for Arduino IDE
The best and easiest way is to use Arduino Library Manager. Search for AsyncWebServer_ESP32_W6100, then select / install the latest version. You can also use this link
- Navigate to AsyncWebServer_ESP32_W6100 page.
- Download the latest release
AsyncWebServer_ESP32_W6100-main.zip. - Extract the zip file to
AsyncWebServer_ESP32_W6100-maindirectory - Copy the whole
AsyncWebServer_ESP32_W6100-mainfolder to Arduino libraries' directory such as~/Arduino/libraries/.
- Install VS Code
- Install PlatformIO
- Install AsyncWebServer_ESP32_W6100 library by using Library Manager. Search for AsyncWebServer_ESP32_W6100 in Platform.io Author's Libraries
- Use included platformio.ini file from examples to ensure that all dependent libraries will installed automatically. Please visit documentation for the other options and examples at Project Configuration File
- This is fully asynchronous server and as such does not run on the
loop()thread. - You can not use
yield()ordelay()or any function that uses them inside the callbacks - The server is smart enough to know when to close the connection and free resources
- You can not send more than one response to a single request
- Listens for connections
- Wraps the new clients into
Request - Keeps track of clients and cleans memory
- Manages
Rewritesand apply them on the request url - Manages
Handlersand attaches them to Requests
- TCP connection is received by the server
- The connection is wrapped inside
Requestobject - When the request head is received (type, url, get params, http version and host),
the server goes through all
Rewrites(in the order they were added) to rewrite the url and inject query parameters, next, it goes through all attachedHandlers(in the order they were added) trying to find one thatcanHandlethe given request. If none are found, the default(catch-all) handler is attached. - The rest of the request is received, calling the
handleUploadorhandleBodymethods of theHandlerif they are needed (POST+File/Body) - When the whole request is parsed, the result is given to the
handleRequestmethod of theHandlerand is ready to be responded to - In the
handleRequestmethod, to theRequestis attached aResponseobject (see below) that will serve the response data back to the client - When the
Responseis sent, the client is closed and freed from the memory
- The
Rewritesare used to rewrite the request url and/or inject get parameters for a specific request url path. - All
Rewritesare evaluated on the request in the order they have been added to the server. - The
Rewritewill change the request url only if the request url (excluding get parameters) is fully match the rewrite url, and when the optionalFiltercallback return true. - Setting a
Filterto theRewriteenables to control when to apply the rewrite, decision can be based on request url, http version, request host/port/target host, get parameters or the request client's localIP or remoteIP. - The
Rewritecan specify a target url with optional get parameters, e.g./to-url?with=params
- The
Handlersare used for executing specific actions to particular requests - One
Handlerinstance can be attached to any request and lives together with the server - Setting a
Filterto theHandlerenables to control when to apply the handler, decision can be based on request url, http version, request host/port/target host, get parameters or the request client's localIP or remoteIP. - The
canHandlemethod is used for handler specific control on whether the requests can be handled and for declaring any interesting headers that theRequestshould parse. Decision can be based on request method, request url, http version, request host/port/target host and get parameters - Once a
Handleris attached to givenRequest(canHandlereturned true) thatHandlertakes care to receive any file/data upload and attach aResponseonce theRequesthas been fully parsed Handlersare evaluated in the order they are attached to the server. ThecanHandleis called only if theFilterthat was set to theHandlerreturn true.- The first
Handlerthat can handle the request is selected, not furtherFilterandcanHandleare called.
- The
Responseobjects are used to send the response data back to the client - The
Responseobject lives with theRequestand is freed on end or disconnect - Different techniques are used depending on the response type to send the data in packets returning back almost immediately and sending the next packet when this one is received. Any time in between is spent to run the user loop and handle other network packets
- Responding asynchronously is probably the most difficult thing for most to understand
- Many different options exist for the user to make responding a background task
AsyncWebServer_ESP32_W6100contains simple template processing engine.- Template processing can be added to most response types.
- Currently it supports only replacing template placeholders with actual values. No conditional processing, cycles, etc.
- Placeholders are delimited with
%symbols. Like this:%TEMPLATE_PLACEHOLDER%. - It works by extracting placeholder name from response text and passing it to user provided function which should return actual value to be used instead of placeholder.
- Since it's user provided function, it is possible for library users to implement conditional processing and cycles themselves.
- Since it's impossible to know the actual response size after template processing step in advance (and, therefore, to include it in response headers), the response becomes chunked.
request->version(); // uint8_t: 0 = HTTP/1.0, 1 = HTTP/1.1
request->method(); // enum: HTTP_GET, HTTP_POST, HTTP_DELETE, HTTP_PUT, HTTP_PATCH, HTTP_HEAD, HTTP_OPTIONS
request->url(); // String: URL of the request (not including host, port or GET parameters)
request->host(); // String: The requested host (can be used for virtual hosting)
request->contentType(); // String: ContentType of the request (not available in Handler::canHandle)
request->contentLength(); // size_t: ContentLength of the request (not available in Handler::canHandle)
request->multipart(); // bool: True if the request has content type "multipart"//List all collected headers
int headers = request->headers();
int i;
for (i=0;i<headers;i++)
{
AsyncWebHeader* h = request->getHeader(i);
Serial.printf("HEADER[%s]: %s\n", h->name().c_str(), h->value().c_str());
}
//get specific header by name
if (request->hasHeader("MyHeader"))
{
AsyncWebHeader* h = request->getHeader("MyHeader");
Serial.printf("MyHeader: %s\n", h->value().c_str());
}
//List all collected headers (Compatibility)
int headers = request->headers();
int i;
for (i=0;i<headers;i++)
{
Serial.printf("HEADER[%s]: %s\n", request->headerName(i).c_str(), request->header(i).c_str());
}
//get specific header by name (Compatibility)
if (request->hasHeader("MyHeader"))
{
Serial.printf("MyHeader: %s\n", request->header("MyHeader").c_str());
}//List all parameters
int params = request->params();
for (int i=0;i<params;i++)
{
AsyncWebParameter* p = request->getParam(i);
if (p->isFile())
{
//p->isPost() is also true
Serial.printf("FILE[%s]: %s, size: %u\n", p->name().c_str(), p->value().c_str(), p->size());
}
else if (p->isPost())
{
Serial.printf("POST[%s]: %s\n", p->name().c_str(), p->value().c_str());
}
else
{
Serial.printf("GET[%s]: %s\n", p->name().c_str(), p->value().c_str());
}
}
//Check if GET parameter exists
if (request->hasParam("download"))
AsyncWebParameter* p = request->getParam("download");
//Check if POST (but not File) parameter exists
if (request->hasParam("download", true))
AsyncWebParameter* p = request->getParam("download", true);
//Check if FILE was uploaded
if (request->hasParam("download", true, true))
AsyncWebParameter* p = request->getParam("download", true, true);
//List all parameters (Compatibility)
int args = request->args();
for (int i=0;i<args;i++)
{
Serial.printf("ARG[%s]: %s\n", request->argName(i).c_str(), request->arg(i).c_str());
}
//Check if parameter exists (Compatibility)
if (request->hasArg("download"))
String arg = request->arg("download");Endpoints which consume JSON can use a special handler to get ready to use JSON data in the request callback:
#include "AsyncJson.h"
#include "ArduinoJson.h"
AsyncCallbackJsonWebHandler* handler = new AsyncCallbackJsonWebHandler("/rest/endpoint", [](AsyncWebServerRequest *request, JsonVariant &json)
{
JsonObject& jsonObj = json.as<JsonObject>();
// ...
});
server.addHandler(handler);//to local url
request->redirect("/login");
//to external url
request->redirect("http://esp8266.com");request->send(404); //Sends 404 File Not FoundAsyncWebServerResponse *response = request->beginResponse(404); //Sends 404 File Not Found
response->addHeader("Server","AsyncWebServer_ESP32_W6100");
request->send(response);request->send(200, "text/plain", "Hello World!");AsyncWebServerResponse *response = request->beginResponse(200, "text/plain", "Hello World!");
response->addHeader("Server","AsyncWebServer");
request->send(response);//read 12 bytes from Serial and send them as Content Type text/plain
request->send(Serial, "text/plain", 12);//read 12 bytes from Serial and send them as Content Type text/plain
AsyncWebServerResponse *response = request->beginResponse(Serial, "text/plain", 12);
response->addHeader("Server","AsyncWebServer_ESP32_W6100");
request->send(response);String processor(const String& var)
{
if (var == "HELLO_FROM_TEMPLATE")
return F("Hello world!");
return String();
}
// ...
//read 12 bytes from Serial and send them as Content Type text/plain
request->send(Serial, "text/plain", 12, processor);String processor(const String& var)
{
if (var == "HELLO_FROM_TEMPLATE")
return F("Hello world!");
return String();
}
// ...
//read 12 bytes from Serial and send them as Content Type text/plain
AsyncWebServerResponse *response = request->beginResponse(Serial, "text/plain", 12, processor);
response->addHeader("Server","AsyncWebServer_ESP32_W6100");
request->send(response);//send 128 bytes as plain text
request->send("text/plain", 128, [](uint8_t *buffer, size_t maxLen, size_t index) -> size_t
{
//Write up to "maxLen" bytes into "buffer" and return the amount written.
//index equals the amount of bytes that have been already sent
//You will not be asked for more bytes once the content length has been reached.
//Keep in mind that you can not delay or yield waiting for more data!
//Send what you currently have and you will be asked for more again
return mySource.read(buffer, maxLen);
});//send 128 bytes as plain text
AsyncWebServerResponse *response = request->beginResponse("text/plain", 128, [](uint8_t *buffer, size_t maxLen, size_t index) -> size_t
{
//Write up to "maxLen" bytes into "buffer" and return the amount written.
//index equals the amount of bytes that have been already sent
//You will not be asked for more bytes once the content length has been reached.
//Keep in mind that you can not delay or yield waiting for more data!
//Send what you currently have and you will be asked for more again
return mySource.read(buffer, maxLen);
});
response->addHeader("Server","AsyncWebServer_ESP32_W6100");
request->send(response);String processor(const String& var)
{
if (var == "HELLO_FROM_TEMPLATE")
return F("Hello world!");
return String();
}
// ...
//send 128 bytes as plain text
request->send("text/plain", 128, [](uint8_t *buffer, size_t maxLen, size_t index) -> size_t
{
//Write up to "maxLen" bytes into "buffer" and return the amount written.
//index equals the amount of bytes that have been already sent
//You will not be asked for more bytes once the content length has been reached.
//Keep in mind that you can not delay or yield waiting for more data!
//Send what you currently have and you will be asked for more again
return mySource.read(buffer, maxLen);
}, processor);String processor(const String& var)
{
if (var == "HELLO_FROM_TEMPLATE")
return F("Hello world!");
return String();
}
// ...
//send 128 bytes as plain text
AsyncWebServerResponse *response = request->beginResponse("text/plain", 128, [](uint8_t *buffer, size_t maxLen, size_t index) -> size_t
{
//Write up to "maxLen" bytes into "buffer" and return the amount written.
//index equals the amount of bytes that have been already sent
//You will not be asked for more bytes once the content length has been reached.
//Keep in mind that you can not delay or yield waiting for more data!
//Send what you currently have and you will be asked for more again
return mySource.read(buffer, maxLen);
}, processor);
response->addHeader("Server","AsyncWebServer_ESP32_W6100");
request->send(response);Used when content length is unknown. Works best if the client supports HTTP/1.1
AsyncWebServerResponse *response = request->beginChunkedResponse("text/plain", [](uint8_t *buffer, size_t maxLen, size_t index) -> size_t
{
//Write up to "maxLen" bytes into "buffer" and return the amount written.
//index equals the amount of bytes that have been already sent
//You will be asked for more data until 0 is returned
//Keep in mind that you can not delay or yield waiting for more data!
return mySource.read(buffer, maxLen);
});
response->addHeader("Server","AsyncWebServer_ESP32_W6100");
request->send(response);Used when content length is unknown. Works best if the client supports HTTP/1.1
String processor(const String& var)
{
if (var == "HELLO_FROM_TEMPLATE")
return F("Hello world!");
return String();
}
// ...
AsyncWebServerResponse *response = request->beginChunkedResponse("text/plain", [](uint8_t *buffer, size_t maxLen, size_t index) -> size_t
{
//Write up to "maxLen" bytes into "buffer" and return the amount written.
//index equals the amount of bytes that have been already sent
//You will be asked for more data until 0 is returned
//Keep in mind that you can not delay or yield waiting for more data!
return mySource.read(buffer, maxLen);
}, processor);
response->addHeader("Server","AsyncWebServer_ESP32_W6100");
request->send(response);AsyncResponseStream *response = request->beginResponseStream("text/html");
response->addHeader("Server","AsyncWebServer_ESP32_W6100");
response->printf("<!DOCTYPE html><html><head><title>Webpage at %s</title></head><body>", request->url().c_str());
response->print("<h2>Hello ");
response->print(request->client()->remoteIP());
response->print("</h2>");
response->print("<h3>General</h3>");
response->print("<ul>");
response->printf("<li>Version: HTTP/1.%u</li>", request->version());
response->printf("<li>Method: %s</li>", request->methodToString());
response->printf("<li>URL: %s</li>", request->url().c_str());
response->printf("<li>Host: %s</li>", request->host().c_str());
response->printf("<li>ContentType: %s</li>", request->contentType().c_str());
response->printf("<li>ContentLength: %u</li>", request->contentLength());
response->printf("<li>Multipart: %s</li>", request->multipart()?"true":"false");
response->print("</ul>");
response->print("<h3>Headers</h3>");
response->print("<ul>");
int headers = request->headers();
for (int i=0;i<headers;i++)
{
AsyncWebHeader* h = request->getHeader(i);
response->printf("<li>%s: %s</li>", h->name().c_str(), h->value().c_str());
}
response->print("</ul>");
response->print("<h3>Parameters</h3>");
response->print("<ul>");
int params = request->params();
for (int i=0;i<params;i++)
{
AsyncWebParameter* p = request->getParam(i);
if (p->isFile())
{
response->printf("<li>FILE[%s]: %s, size: %u</li>", p->name().c_str(), p->value().c_str(), p->size());
}
else if (p->isPost())
{
response->printf("<li>POST[%s]: %s</li>", p->name().c_str(), p->value().c_str());
}
else
{
response->printf("<li>GET[%s]: %s</li>", p->name().c_str(), p->value().c_str());
}
}
response->print("</ul>");
response->print("</body></html>");
//send the response last
request->send(response);This way of sending Json is great for when the result is below 4KB
#include "AsyncJson.h"
#include "ArduinoJson.h"
AsyncResponseStream *response = request->beginResponseStream("application/json");
DynamicJsonBuffer jsonBuffer;
JsonObject &root = jsonBuffer.createObject();
root["heap"] = ESP.getFreeHeap();
root["ssid"] = WiFi.SSID();
root.printTo(*response);
request->send(response);This response can handle really large Json objects (tested to 40KB)
There isn't any noticeable speed decrease for small results with the method above
Since ArduinoJson does not allow reading parts of the string, the whole Json has to be passed every time a chunks needs to be sent, which shows speed decrease proportional to the resulting json packets
#include "AsyncJson.h"
#include "ArduinoJson.h"
AsyncJsonResponse * response = new AsyncJsonResponse();
response->addHeader("Server","AsyncWebServer");
JsonObject& root = response->getRoot();
root["IP"] = Ethernet.localIP();
response->setLength();
request->send(response);It is possible to rewrite the request url with parameter matchg. Here is an example with one parameter: Rewrite for example "/radio/{frequence}" -> "/radio?f={frequence}"
class OneParamRewrite : public AsyncWebRewrite
{
protected:
String _urlPrefix;
int _paramIndex;
String _paramsBackup;
public:
OneParamRewrite(const char* from, const char* to)
: AsyncWebRewrite(from, to)
{
_paramIndex = _from.indexOf('{');
if ( _paramIndex >=0 && _from.endsWith("}"))
{
_urlPrefix = _from.substring(0, _paramIndex);
int index = _params.indexOf('{');
if (index >= 0)
{
_params = _params.substring(0, index);
}
}
else
{
_urlPrefix = _from;
}
_paramsBackup = _params;
}
bool match(AsyncWebServerRequest *request) override
{
if (request->url().startsWith(_urlPrefix))
{
if (_paramIndex >= 0)
{
_params = _paramsBackup + request->url().substring(_paramIndex);
}
else
{
_params = _paramsBackup;
}
return true;
}
else
{
return false;
}
}
};Usage:
server.addRewrite( new OneParamRewrite("/radio/{frequence}", "/radio?f={frequence}") );Filters can be set to Rewrite or Handler in order to control when to apply the rewrite and consider the handler.
A filter is a callback function that evaluates the request and return a boolean true to include the item
or false to exclude it.
Some responses are implemented, but you should not use them, because they do not conform to HTTP. The following example will lead to unclean close of the connection and more time wasted than providing the length of the content
//This is used as fallback for chunked responses to HTTP/1.0 Clients
request->send("text/plain", 0, [](uint8_t *buffer, size_t maxLen, size_t index) -> size_t
{
//Write up to "maxLen" bytes into "buffer" and return the amount written.
//You will be asked for more data until 0 is returned
//Keep in mind that you can not delay or yield waiting for more data!
return mySource.read(buffer, maxLen);
});The server includes a web socket plugin which lets you define different WebSocket locations to connect to without starting another listening service or using different port
void onEvent(AsyncWebSocket * server, AsyncWebSocketClient * client, AwsEventType type, void * arg, uint8_t *data, size_t len)
{
if (type == WS_EVT_CONNECT)
{
//client connected
Serial.printf("ws[%s][%u] connect\n", server->url(), client->id());
client->printf("Hello Client %u :)", client->id());
client->ping();
}
else if (type == WS_EVT_DISCONNECT)
{
//client disconnected
Serial.printf("ws[%s][%u] disconnect: %u\n", server->url(), client->id());
}
else if (type == WS_EVT_ERROR)
{
//error was received from the other end
Serial.printf("ws[%s][%u] error(%u): %s\n", server->url(), client->id(), *((uint16_t*)arg), (char*)data);
}
else if (type == WS_EVT_PONG)
{
//pong message was received (in response to a ping request maybe)
Serial.printf("ws[%s][%u] pong[%u]: %s\n", server->url(), client->id(), len, (len)?(char*)data:"");
}
else if (type == WS_EVT_DATA)
{
//data packet
AwsFrameInfo * info = (AwsFrameInfo*)arg;
if (info->final && info->index == 0 && info->len == len)
{
//the whole message is in a single frame and we got all of it's data
Serial.printf("ws[%s][%u] %s-message[%llu]: ", server->url(), client->id(), (info->opcode == WS_TEXT)?"text":"binary", info->len);
if (info->opcode == WS_TEXT)
{
data[len] = 0;
Serial.printf("%s\n", (char*)data);
}
else
{
for (size_t i=0; i < info->len; i++)
{
Serial.printf("%02x ", data[i]);
}
Serial.printf("\n");
}
if (info->opcode == WS_TEXT)
client->text("I got your text message");
else
client->binary("I got your binary message");
}
else
{
//message is comprised of multiple frames or the frame is split into multiple packets
if (info->index == 0)
{
if (info->num == 0)
Serial.printf("ws[%s][%u] %s-message start\n", server->url(), client->id(), (info->message_opcode == WS_TEXT)?"text":"binary");
Serial.printf("ws[%s][%u] frame[%u] start[%llu]\n", server->url(), client->id(), info->num, info->len);
}
Serial.printf("ws[%s][%u] frame[%u] %s[%llu - %llu]: ", server->url(), client->id(), info->num, (info->message_opcode == WS_TEXT)?"text":"binary", info->index, info->index + len);
if (info->message_opcode == WS_TEXT)
{
data[len] = 0;
Serial.printf("%s\n", (char*)data);
}
else
{
for (size_t i=0; i < len; i++){
Serial.printf("%02x ", data[i]);
}
Serial.printf("\n");
}
if ((info->index + len) == info->len)
{
Serial.printf("ws[%s][%u] frame[%u] end[%llu]\n", server->url(), client->id(), info->num, info->len);
if (info->final)
{
Serial.printf("ws[%s][%u] %s-message end\n", server->url(), client->id(), (info->message_opcode == WS_TEXT)?"text":"binary");
if (info->message_opcode == WS_TEXT)
client->text("I got your text message");
else
client->binary("I got your binary message");
}
}
}
}
}//Server methods
AsyncWebSocket ws("/ws");
//printf to a client
ws.printf((uint32_t)client_id, arguments...);
//printf to all clients
ws.printfAll(arguments...);
//send text to a client
ws.text((uint32_t)client_id, (char*)text);
ws.text((uint32_t)client_id, (uint8_t*)text, (size_t)len);
//send text to all clients
ws.textAll((char*)text);
ws.textAll((uint8_t*)text, (size_t)len);
//send binary to a client
ws.binary((uint32_t)client_id, (char*)binary);
ws.binary((uint32_t)client_id, (uint8_t*)binary, (size_t)len);
ws.binary((uint32_t)client_id, flash_binary, 4);
//send binary to all clients
ws.binaryAll((char*)binary);
ws.binaryAll((uint8_t*)binary, (size_t)len);
//HTTP Authenticate before switch to Websocket protocol
ws.setAuthentication("user", "pass");
//client methods
AsyncWebSocketClient * client;
//printf
client->printf(arguments...);
//send text
client->text((char*)text);
client->text((uint8_t*)text, (size_t)len);
//send binary
client->binary((char*)binary);
client->binary((uint8_t*)binary, (size_t)len);When sending a web socket message using the above methods a buffer is created. Under certain circumstances you might want to manipulate or populate this buffer directly from your application, for example to prevent unnecessary duplications of the data. This example below shows how to create a buffer and print data to it from an ArduinoJson object then send it.
void sendDataWs(AsyncWebSocketClient * client)
{
DynamicJsonBuffer jsonBuffer;
JsonObject& root = jsonBuffer.createObject();
root["a"] = "abc";
root["b"] = "abcd";
root["c"] = "abcde";
root["d"] = "abcdef";
root["e"] = "abcdefg";
size_t len = root.measureLength();
AsyncWebSocketMessageBuffer * buffer = ws.makeBuffer(len); // creates a buffer (len + 1) for you.
if (buffer)
{
root.printTo((char *)buffer->get(), len + 1);
if (client)
{
client->text(buffer);
}
else
{
ws.textAll(buffer);
}
}
}Browsers sometimes do not correctly close the websocket connection, even when the close() function is called in javascript. This will eventually exhaust the web server's resources and will cause the server to crash. Periodically calling the cleanClients() function from the main loop() function limits the number of clients by closing the oldest client when the maximum number of clients has been exceeded. This can called be every cycle, however, if you wish to use less power, then calling as infrequently as once per second is sufficient.
void loop()
{
ws.cleanupClients();
}The server includes EventSource (Server-Sent Events) plugin which can be used to send short text events to the browser.
Difference between EventSource and WebSockets is that EventSource is single direction, text-only protocol.
AsyncWebServer server(80);
AsyncEventSource events("/events");
void setup()
{
// setup ......
events.onConnect([](AsyncEventSourceClient *client)
{
if (client->lastId())
{
Serial.printf("Client reconnected! Last message ID that it got is: %u\n", client->lastId());
}
//send event with message "hello!", id current millis
// and set reconnect delay to 1 second
client->send("hello!",NULL,millis(),1000);
});
//HTTP Basic authentication
events.setAuthentication("user", "pass");
server.addHandler(&events);
// setup ......
}
void loop()
{
if (eventTriggered)
{
// your logic here
//send event "myevent"
events.send("my event content","myevent",millis());
}
}if (!!window.EventSource)
{
var source = new EventSource('/events');
source.addEventListener('open', function(e)
{
console.log("Events Connected");
}, false);
source.addEventListener('error', function(e)
{
if (e.target.readyState != EventSource.OPEN)
{
console.log("Events Disconnected");
}
}, false);
source.addEventListener('message', function(e)
{
console.log("message", e.data);
}, false);
source.addEventListener('myevent', function(e)
{
console.log("myevent", e.data);
}, false);
}Server goes through handlers in same order as they were added. You can't simple add handler with same path to override them. To remove handler:
// save callback for particular URL path
auto handler = server.on("/some/path", [](AsyncWebServerRequest *request)
{
//do something useful
});
// when you don't need handler anymore remove it
server.removeHandler(&handler);
// same with rewrites
server.removeRewrite(&someRewrite);
server.onNotFound([](AsyncWebServerRequest *request)
{
request->send(404);
});
// remove server.onNotFound handler
server.onNotFound(NULL);
// remove all rewrites, handlers and onNotFound/onFileUpload/onRequestBody callbacks
server.reset();#if !( defined(ESP32) )
#error This code is designed for (ESP32 + W6100) to run on ESP32 platform! Please check your Tools->Board setting.
#endif
#include <Arduino.h>
#define _ASYNC_WEBSERVER_LOGLEVEL_ 2
// Enter a MAC address and IP address for your controller below.
#define NUMBER_OF_MAC 20
byte mac[][NUMBER_OF_MAC] =
{
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0x01 },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xBE, 0x02 },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0x03 },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xBE, 0x04 },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0x05 },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xBE, 0x06 },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0x07 },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xBE, 0x08 },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0x09 },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xBE, 0x0A },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0x0B },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xBE, 0x0C },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0x0D },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xBE, 0x0E },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0x0F },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xBE, 0x10 },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0x11 },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xBE, 0x12 },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0x13 },
{ 0xDE, 0xAD, 0xBE, 0xEF, 0xBE, 0x14 },
};
// Select the IP address according to your local network
IPAddress myIP(192, 168, 2, 232);
IPAddress myGW(192, 168, 2, 1);
IPAddress mySN(255, 255, 255, 0);
// Google DNS Server IP
IPAddress myDNS(8, 8, 8, 8);
//////////////////////////////////////////////////////////
// Optional values to override default settings
// Don't change unless you know what you're doing
//#define ETH_SPI_HOST SPI3_HOST
//#define SPI_CLOCK_MHZ 25
// Must connect INT to GPIOxx or not working
//#define INT_GPIO 4
//#define MISO_GPIO 19
//#define MOSI_GPIO 23
//#define SCK_GPIO 18
//#define CS_GPIO 5
//////////////////////////////////////////////////////////
#include <AsyncTCP.h>
#include <AsyncWebServer_ESP32_W6100.h>
AsyncWebServer server(80);
void handleRoot(AsyncWebServerRequest *request)
{
request->send(200, "text/plain", String("Hello from Async_HelloServer on ") + ARDUINO_BOARD );
}
void handleNotFound(AsyncWebServerRequest *request)
{
String message = "File Not Found\n\n";
message += "URI: ";
//message += server.uri();
message += request->url();
message += "\nMethod: ";
message += (request->method() == HTTP_GET) ? "GET" : "POST";
message += "\nArguments: ";
message += request->args();
message += "\n";
for (uint8_t i = 0; i < request->args(); i++)
{
message += " " + request->argName(i) + ": " + request->arg(i) + "\n";
}
request->send(404, "text/plain", message);
}
void setup()
{
Serial.begin(115200);
while (!Serial && millis() < 5000);
delay(200);
Serial.print(F("\nStart Async_HelloServer on "));
Serial.print(ARDUINO_BOARD);
Serial.print(F(" with "));
Serial.println(SHIELD_TYPE);
Serial.println(ASYNC_WEBSERVER_ESP32_W6100_VERSION);
AWS_LOGWARN(F("Default SPI pinout:"));
AWS_LOGWARN1(F("SPI_HOST:"), ETH_SPI_HOST);
AWS_LOGWARN1(F("MOSI:"), MOSI_GPIO);
AWS_LOGWARN1(F("MISO:"), MISO_GPIO);
AWS_LOGWARN1(F("SCK:"), SCK_GPIO);
AWS_LOGWARN1(F("CS:"), CS_GPIO);
AWS_LOGWARN1(F("INT:"), INT_GPIO);
AWS_LOGWARN1(F("SPI Clock (MHz):"), SPI_CLOCK_MHZ);
AWS_LOGWARN(F("========================="));
///////////////////////////////////
// To be called before ETH.begin()
ESP32_W6100_onEvent();
// start the ethernet connection and the server:
// Use DHCP dynamic IP and random mac
//bool begin(int MISO_GPIO, int MOSI_GPIO, int SCLK_GPIO, int CS_GPIO, int INT_GPIO, int SPI_CLOCK_MHZ,
// int SPI_HOST, uint8_t *W6100_Mac = W6100_Default_Mac);
ETH.begin( MISO_GPIO, MOSI_GPIO, SCK_GPIO, CS_GPIO, INT_GPIO, SPI_CLOCK_MHZ, ETH_SPI_HOST );
//ETH.begin( MISO_GPIO, MOSI_GPIO, SCK_GPIO, CS_GPIO, INT_GPIO, SPI_CLOCK_MHZ, ETH_SPI_HOST, mac[millis() % NUMBER_OF_MAC] );
// Static IP, leave without this line to get IP via DHCP
//bool config(IPAddress local_ip, IPAddress gateway, IPAddress subnet, IPAddress dns1 = 0, IPAddress dns2 = 0);
//ETH.config(myIP, myGW, mySN, myDNS);
ESP32_W6100_waitForConnect();
///////////////////////////////////
server.on("/", HTTP_GET, [](AsyncWebServerRequest * request)
{
handleRoot(request);
});
server.on("/inline", [](AsyncWebServerRequest * request)
{
request->send(200, "text/plain", "This works as well");
});
server.onNotFound(handleNotFound);
server.begin();
Serial.print(F("HTTP EthernetWebServer is @ IP : "));
Serial.println(ETH.localIP());
}
void loop()
{
}#include <Arduino.h>
#include <AsyncWebServer_ESP32_W6100.h>
...
void handleRequest(AsyncWebServerRequest *request){}
class WebClass
{
public :
AsyncWebServer classWebServer = AsyncWebServer(81);
WebClass(){};
void classRequest (AsyncWebServerRequest *request){}
void begin()
{
// attach global request handler
classWebServer.on("/example", HTTP_ANY, handleRequest);
// attach class request handler
classWebServer.on("/example", HTTP_ANY, std::bind(&WebClass::classRequest, this, std::placeholders::_1));
}
};
AsyncWebServer globalWebServer(80);
WebClass webClassInstance;
void setup()
{
// attach global request handler
globalWebServer.on("/example", HTTP_ANY, handleRequest);
// attach class request handler
globalWebServer.on("/example", HTTP_ANY, std::bind(&WebClass::classRequest, webClassInstance, std::placeholders::_1));
}
void loop()
{
}// Disable client connections if it was activated
if ( ws.enabled() )
ws.enable(false);
// enable client connections if it was disabled
if ( !ws.enabled() )
ws.enable(true);In some cases, such as when working with CORS, or with some sort of custom authentication system, you might need to define a header that should get added to all responses (including static, websocket and EventSource). The DefaultHeaders singleton allows you to do this.
Example:
DefaultHeaders::Instance().addHeader("Access-Control-Allow-Origin", "*");
webServer.begin();NOTE: You will still need to respond to the OPTIONS method for CORS pre-flight in most cases. (unless you are only using GET)
This is one option:
webServer.onNotFound([](AsyncWebServerRequest *request)
{
if (request->method() == HTTP_OPTIONS)
{
request->send(200);
}
else
{
request->send(404);
}
});With path variable you can create a custom regex rule for a specific parameter in a route.
For example we want a sensorId parameter in a route rule to match only a integer.
server.on("^\\/sensor\\/([0-9]+)$", HTTP_GET, [] (AsyncWebServerRequest *request)
{
String sensorId = request->pathArg(0);
});NOTE: All regex patterns starts with ^ and ends with $
To enable the Path variable support, you have to define the buildflag -DASYNCWEBSERVER_REGEX.
For Arduino IDE create/update platform.local.txt:
Windows: C:\Users(username)\AppData\Local\Arduino15\packages\{espxxxx}\hardware\espxxxx\{version}\platform.local.txt
Linux: ~/.arduino15/packages/{espxxxx}/hardware/{espxxxx}/{version}/platform.local.txt
Add/Update the following line:
compiler.cpp.extra_flags=-DDASYNCWEBSERVER_REGEX
For platformio modify platformio.ini:
[env:myboard]
build_flags =
-DASYNCWEBSERVER_REGEXNOTE: By enabling ASYNCWEBSERVER_REGEX, <regex> will be included. This will add an 100k to your binary.
You can change the INT pin to another one. Default is GPIO4
// Must connect INT to GPIOxx or not working
#define INT_GPIO 4
| W6100 | <---> | ESP32 |
|---|---|---|
| MOSI | <---> | GPIO23 |
| MISO | <---> | GPIO19 |
| SCK | <---> | GPIO18 |
| CS/SS | <---> | GPIO5 |
| INT | <---> | GPIO4 |
| RST | <---> | RST |
| GND | <---> | GND |
| 3.3V | <---> | 3.3V |
- Async_AdvancedWebServer
- Async_AdvancedWebServer_MemoryIssues_SendArduinoString
- Async_AdvancedWebServer_MemoryIssues_Send_CString
- Async_AdvancedWebServer_SendChunked
- Async_HelloServer
- Async_HelloServer2
- Async_HttpBasicAuth
- AsyncMultiWebServer_ESP32_W6100
- Async_PostServer
- Async_RegexPatterns_ESP32_W6100
- AsyncSimpleServer_ESP32_W6100
- AsyncWebServer_SendChunked
- Async_WebSocketsServer
- MQTTClient_Auth
- MQTTClient_Basic
- MQTT_ThingStream
Example Async_AdvancedWebServer
You can access the Async Advanced WebServer @ the server IP
Following are debug terminal output and screen shots when running example AsyncMultiWebServer_ESP32_W6100 on ESP32_DEV with LwIP W6100, using ESP32 core v2.0.0+, to demonstrate the operation of 3 independent AsyncWebServers on 3 different ports and how to handle the complicated AsyncMultiWebServers.
Start AsyncMultiWebServer_ESP32_W6100 on ESP32_DEV with ESP32_W6100
AsyncWebServer_ESP32_W6100 v1.6.4 for core v2.0.0+
[AWS] Default SPI pinout:
[AWS] SPI_HOST: 2
[AWS] MOSI: 23
[AWS] MISO: 19
[AWS] SCK: 18
[AWS] CS: 5
[AWS] INT: 4
[AWS] SPI Clock (MHz): 25
[AWS] =========================
ETH Started
ETH Connected
ETH MAC: 0C:B8:15:D8:01:D7, IPv4: 192.168.2.158
FULL_DUPLEX, 100Mbps
Connected to network. IP = 192.168.2.158
Initialize multiServer OK, serverIndex = 0, port = 8080
HTTP server started at ports 8080
Initialize multiServer OK, serverIndex = 1, port = 8081
HTTP server started at ports 8081
Initialize multiServer OK, serverIndex = 2, port = 8082
HTTP server started at ports 8082You can access the Async Advanced WebServers @ the server IP and corresponding ports (8080, 8081 and 8082)
Following is the debug terminal and screen shot when running example Async_AdvancedWebServer_MemoryIssues_Send_CString, on ESP32_DEV with LwIP W6100, to demonstrate the new and powerful HEAP-saving feature
Start Async_AdvancedWebServer_MemoryIssues_Send_CString on ESP32_DEV with ESP32_W6100
AsyncWebServer_ESP32_W6100 v1.6.4 for core v2.0.0+
[AWS] Default SPI pinout:
[AWS] SPI_HOST: 2
[AWS] MOSI: 23
[AWS] MISO: 19
[AWS] SCK: 18
[AWS] CS: 5
[AWS] INT: 4
[AWS] SPI Clock (MHz): 25
[AWS] =========================
ETH Started
ETH Connected
ETH MAC: 0C:B8:15:D8:01:D7, IPv4: 192.168.2.158
FULL_DUPLEX, 100Mbps
HTTP EthernetWebServer is @ IP : 192.168.2.158
HEAP DATA - Pre Create Arduino String Max heap: 316288 Free heap: 214884 Used heap: 101404
..
HEAP DATA - Pre Send Max heap: 316288 Free heap: 210544 Used heap: 105744
HEAP DATA - Post Send Max heap: 316288 Free heap: 204084 Used heap: 112204
.
HEAP DATA - Post Send Max heap: 316288 Free heap: 203768 Used heap: 112520
..
HEAP DATA - Post Send Max heap: 316288 Free heap: 203536 Used heap: 112752
..
HEAP DATA - Post Send Max heap: 316288 Free heap: 203204 Used heap: 113084
.
HEAP DATA - Post Send Max heap: 316288 Free heap: 202988 Used heap: 113300
..
HEAP DATA - Post Send Max heap: 316288 Free heap: 202896 Used heap: 113392
.While using Arduino String, the HEAP usage is very large
Start Async_AdvancedWebServer_MemoryIssues_SendArduinoString on ESP32_DEV with ESP32_W6100
AsyncWebServer_ESP32_W6100 v1.6.4 for core v2.0.0+
[AWS] Default SPI pinout:
[AWS] SPI_HOST: 2
[AWS] MOSI: 23
[AWS] MISO: 19
[AWS] SCK: 18
[AWS] CS: 5
[AWS] INT: 4
[AWS] SPI Clock (MHz): 25
[AWS] =========================
ETH Started
ETH Connected
ETH MAC: 0C:B8:15:D8:01:D7, IPv4: 192.168.2.158
FULL_DUPLEX, 100Mbps
HTTP EthernetWebServer is @ IP : 192.168.2.158
HEAP DATA - Pre Create Arduino String Max heap: 316560 Free heap: 255156 Used heap: 61404
..
HEAP DATA - Pre Send Max heap: 316560 Free heap: 210892 Used heap: 105668
HEAP DATA - Post Send Max heap: 316560 Free heap: 173148 Used heap: 143412
..
HEAP DATA - Post Send Max heap: 316560 Free heap: 173136 Used heap: 143424
.You can access the Async Advanced WebServers at the displayed server IP, e.g. 192.168.2.158
Following is debug terminal output when running example Async_AdvancedWebServer_SendChunked on ESP32_DEV with LwIP W6100, using ESP32 core v2.0.0+, to demo how to use beginChunkedResponse() to send large html in chunks
Start Async_AdvancedWebServer_SendChunked on ESP32_DEV with ESP32_W6100
AsyncWebServer_ESP32_W6100 v1.6.4 for core v2.0.0+
[AWS] Default SPI pinout:
[AWS] SPI_HOST: 2
[AWS] MOSI: 23
[AWS] MISO: 19
[AWS] SCK: 18
[AWS] CS: 5
[AWS] INT: 4
[AWS] SPI Clock (MHz): 25
[AWS] =========================
ETH Started
ETH Connected
ETH MAC: 0C:B8:15:D8:01:D7, IPv4: 192.168.2.158
FULL_DUPLEX, 100Mbps
AsyncWebServer is @ IP : 192.168.2.158
.[AWS] Total length to send in chunks = 31259
[AWS] Bytes sent in chunk = 5620
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 4300
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 4203
[AWS] Bytes sent in chunk = 0
.[AWS] Total length to send in chunks = 31279
[AWS] Bytes sent in chunk = 5620
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 2864
[AWS] Bytes sent in chunk = 2864
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 2864
[AWS] Bytes sent in chunk = 2787
[AWS] Bytes sent in chunk = 0You can access the Async Advanced WebServers @ the server IP
Following is debug terminal output when running example AsyncWebServer_SendChunked on ESP32_DEV with LwIP W6100, using ESP32 core v2.0.0+, to demo how to use beginChunkedResponse() to send large html in chunks
Start AsyncWebServer_SendChunked on ESP32_DEV with ESP32_W6100
AsyncWebServer_ESP32_W6100 v1.6.4 for core v2.0.0+
[AWS] Default SPI pinout:
[AWS] SPI_HOST: 2
[AWS] MOSI: 23
[AWS] MISO: 19
[AWS] SCK: 18
[AWS] CS: 5
[AWS] INT: 4
[AWS] SPI Clock (MHz): 25
[AWS] =========================
ETH Started
ETH Connected
ETH MAC: 0C:B8:15:D8:01:D7, IPv4: 192.168.2.158
FULL_DUPLEX, 100Mbps
AsyncWebServer is @ IP : 192.168.2.158
.[AWS] Total length to send in chunks = 47802
[AWS] Bytes sent in chunk = 5624
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 4300
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 1428
[AWS] Bytes sent in chunk = 4300
[AWS] Bytes sent in chunk = 2864
[AWS] Bytes sent in chunk = 2864
[AWS] Bytes sent in chunk = 2864
[AWS] Bytes sent in chunk = 2864
[AWS] Bytes sent in chunk = 2864
[AWS] Bytes sent in chunk = 2122
[AWS] Bytes sent in chunk = 0Following is debug terminal output when running example Async_WebSocketsServer on ESP32_DEV with LwIP W6100, using ESP32 core v2.0.0+, to demo how to use Async_WebSocketsServer feature
Starting Async_WebSocketsServer on ESP32_DEV with ESP32_W6100
AsyncWebServer_ESP32_W6100 v1.6.4 for core v2.0.0+
[AWS] Default SPI pinout:
[AWS] SPI_HOST: 2
[AWS] MOSI: 23
[AWS] MISO: 19
[AWS] SCK: 18
[AWS] CS: 5
[AWS] INT: 4
[AWS] SPI Clock (MHz): 25
[AWS] =========================
ETH Started
ETH Connected
ETH MAC: 0C:B8:15:D8:01:D7, IPv4: 192.168.2.158
FULL_DUPLEX, 100Mbps
ws[Server: /ws][ClientID: 1] WSClient connected
ws[Server: /ws][ClientID: 1] WSClient disconnected
ws[Server: /ws][ClientID: 2] WSClient connected
ws[Server: /ws][ClientID: 3] WSClient connectedFollowing is debug terminal output when running example Async_HTTPBasicAuth on ESP32_DEV with LwIP W6100, using ESP32 core v2.0.0+, to demo how to use Async_Auth feature
Start Async_HTTPBasicAuth on ESP32_DEV with ESP32_W6100
AsyncWebServer_ESP32_W6100 v1.6.4 for core v2.0.0+
[AWS] Default SPI pinout:
[AWS] SPI_HOST: 2
[AWS] MOSI: 23
[AWS] MISO: 19
[AWS] SCK: 18
[AWS] CS: 5
[AWS] INT: 4
[AWS] SPI Clock (MHz): 25
[AWS] =========================
ETH Started
ETH Connected
ETH MAC: 0C:B8:15:D8:01:D7, IPv4: 192.168.2.158
FULL_DUPLEX, 100Mbps
Async_HttpBasicAuth started @ IP : 192.168.2.158
Open http://192.168.2.158/ in your browser to see it working
Login using username = admin and password = esp32_W6100Debug is enabled by default on Serial. Debug Level from 0 to 4. To disable, change the ETHERNET_WEBSERVER_LOGLEVEL to 0
// Use this to output debug msgs to Serial
#define DEBUG_ASYNC_WEBSERVER_PORT Serial
// Use this to disable all output debug msgs
// Debug Level from 0 to 4
#define _ASYNC_WEBSERVER_LOGLEVEL_ 0If you get compilation errors, more often than not, you may need to install a newer version of Arduino IDE, the Arduino ESP32 core or depending libraries.
Sometimes, the library will only work if you update the ESP32 core to the latest version because I'm always using the latest cores /libraries.
Submit issues to: AsyncWebServer_ESP32_W6100 issues
- Fix bug. Add enhancement
- Add support to more Ethernet shields, such as DP83848, TLK110, IP101, RTL8201, DM9051, KSZ8041, KSZ8081, etc.
- Add
LittleFSsupport to use with new cores
- Initial port to
ESP32boards usingLwIP W6100Ethernet. - Add more examples.
- Add debugging features.
- Add Table-of-Contents and Version String
- Display compiler
#warningonly whenDEBUG_LEVELis 3+ - Fix
AsyncWebSocketbug - Support using
CStringto save heap to sendvery large data. Check request->send(200, textPlainStr, jsonChartDataCharStr); - Without using String Class - to save heap #8 - Add examples Async_AdvancedWebServer_SendChunked and AsyncWebServer_SendChunked to demo how to use
beginChunkedResponse()to send largehtmlin chunks - Use
allman astyleand addutils - Add
Async_WebSocketsServer,Async_HttpBasicAuthandMQTTexamples - Using
SPI_DMA_CH_AUTOinstead of manually selected
- Based on and modified from Hristo Gochkov's ESPAsyncWebServer. Many thanks to Hristo Gochkov for great ESPAsyncWebServer Library
 ⭐️⭐️ Hristo Gochkov |
If you want to contribute to this project:
- Report bugs and errors
- Ask for enhancements
- Create issues and pull requests
- Tell other people about this library
- The library is licensed under GPLv3
-
Copyright (c) 2016- Hristo Gochkov
-
Copyright (c) 2023- Khoi Hoang