-
Notifications
You must be signed in to change notification settings - Fork 1
/
find_signed_nanopubs_with_pattern.rq
56 lines (54 loc) · 1.53 KB
/
find_signed_nanopubs_with_pattern.rq
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
#+ summary: Find signed nanopublications for the given triple pattern
#+ method: GET
#+ pagination: 1000
#+ endpoint_in_url: False
prefix np: <http://www.nanopub.org/nschema#>
prefix npa: <http://purl.org/nanopub/admin/>
prefix npx: <http://purl.org/nanopub/x/>
prefix xsd: <http://www.w3.org/2001/XMLSchema#>
prefix dct: <http://purl.org/dc/terms/>
select ?np ?graphpred ?subj ?pred ?obj ?date ?pubkey ?superseded ?retracted where {
graph npa:graph {
?np npa:hasHeadGraph ?h .
?np npa:creationDay ?__day_iri .
?np npa:creationMonth ?__month_iri .
?np npa:creationYear ?__year_iri .
?np dct:created ?date .
?np npa:hasValidSignatureForPublicKey ?__pubkey_xsd_string .
bind(?__pubkey_xsd_string as ?pubkey)
}
graph ?h {
?np ?__graphpred_iri ?g .
bind(?__graphpred_iri as ?graphpred)
}
graph ?g {
?__subj_iri ?__pred_iri ?__obj_iri .
bind(?__subj_iri as ?subj)
bind(?__pred_iri as ?pred)
bind(?__obj_iri as ?obj)
}
bind(exists {
graph npa:graph {
?newversion npa:hasHeadGraph ?nh .
?newversion npa:hasValidSignatureForPublicKey ?pubkey .
}
graph ?nh {
?newversion np:hasPublicationInfo ?ni .
}
graph ?ni {
?newversion npx:supersedes ?np .
}
} as ?superseded )
bind(exists {
graph npa:graph {
?retraction npa:hasHeadGraph ?rh .
?retraction npa:hasValidSignatureForPublicKey ?pubkey .
}
graph ?rh {
?retraction np:hasAssertion ?ra .
}
graph ?ra {
?somebody npx:retracts ?np .
}
} as ?retracted )
}