Test pump model with different values for pressure to validate parameterization

[MatthiasEckhart]

Dear All,
first of all, I would like to thank the maintainers for developing this library and providing a comprehensive documentation. In particular, the user guides and recorded screencasts have been extremely helpful.

I am a novice in the field of modeling physical systems and I am currently trying to model a rather basic fluid system composed of two water tanks, two valves, and a centrifugal pump. Since I am still a beginner, I have tried to compartmentalize the model, ensuring that I can test each component in isolation.

Context: My main issue is modeling the centrifugal pump and, in particular, validating that the parameterization is correct.
In the datasheet of the pump that I want to model, there is a p-Q diagram that looks like this:

The pump has a maximum differential pressure of 0.7 bar and a maximum free flow of 8 L/min. Furthermore, the maximum RPM for this particular pump is 10,000. Note that I have plotted red points on the line to better illustrate which performance data points I have used to parameterize the flow characteristics.

Based on this, I have created the following pump data:

record M510S_Data
  "Pump data for a TCS micropumps M510 pump"
  extends Buildings.Fluid.Movers.Data.Generic(
    speed_rpm_nominal=10000,
    use_powerCharacteristic=false,
    pressure(V_flow=({0.0, 1.0, 2.0, 3.0, 4.0, 5.0, 6.0, 7.0, 8.0}/60)*0.001, dp={-8/(-(8/0.7)), -7/(-(8/0.7)), -6/(-(8/0.7)), -5/(-(8/0.7)), -4/(-(8/0.7)), -3/(-(8/0.7)), -2/(-(8/0.7)), -1/(-(8/0.7)), 0/(-(8/0.7))}*100000), 
    motorCooledByFluid=true);
  annotation (
defaultComponentPrefixes="parameter",
defaultComponentName="per",
Documentation(info=""));
end M510S_Data;

The pump data is used in the following model:

model M510S_19_MBL

package Medium = Buildings.Media.Water;
  Buildings.Fluid.Movers.SpeedControlled_Nrpm pump1(redeclare package Medium = Medium, redeclare replaceable
      M510S_Data per,
      energyDynamics=Modelica.Fluid.Types.Dynamics.SteadyState,
    y_start=1) annotation(
    Placement(visible = true, transformation(origin = {0, 40}, extent = {{-10, -10}, {10, 10}}, rotation = 0)));
   Modelica.Blocks.Sources.Constant rpm1(k= 10000) "Pump speed control signal"
    annotation (Placement(visible = true, transformation(extent = {{-32, 72}, {-20, 84}}, rotation = 0)));
  Buildings.Fluid.Sources.Boundary_pT source(redeclare package Medium = Medium, nPorts = 1)  annotation(
    Placement(visible = true, transformation(origin = {-60, 40}, extent = {{-10, -10}, {10, 10}}, rotation = 0)));
  Buildings.Fluid.MixingVolumes.MixingVolume tank1(redeclare package Medium = Medium, V = 1, m_flow_nominal = 1, nPorts = 2) annotation(
    Placement(visible = true, transformation(origin = {56, 50}, extent = {{-10, -10}, {10, 10}}, rotation = 0)));
  Buildings.Fluid.Sources.Boundary_pT bou(redeclare package Medium = Medium, nPorts = 1)  annotation(
    Placement(visible = true, transformation(origin = {60, -8}, extent = {{-10, -10}, {10, 10}}, rotation = 0)));
equation
  connect(source.ports[1], pump1.port_a) annotation(
    Line(points = {{-50, 40}, {-10, 40}}, color = {0, 127, 255}));
  connect(rpm1.y, pump1.Nrpm) annotation(
    Line(points = {{-20, 78}, {0, 78}, {0, 52}}, color = {0, 0, 127}));
  connect(pump1.port_b, tank1.ports[1]) annotation(
    Line(points = {{10, 40}, {56, 40}}, color = {0, 127, 255}));
  connect(tank1.ports[2], bou.ports[1]) annotation(
    Line(points = {{56, 40}, {56, 19}, {70, 19}, {70, -8}}, color = {0, 127, 255}));
  annotation(
    uses(Buildings(version = "9.1.0"), Modelica(version = "4.0.0")));
end M510S_19_MBL;

The model diagram looks like this:

I have added the Buildings.Fluid.Sources.Boundary_pT element named bou to set the reference pressure.

When I run the simulation for 60 seconds, I expect that the fluid level in the tank is 8 liters. In fact, the simulation results seem to be in line with my expectation: tank1.ports[1].m_flow shows 0.132745 kg/s (i.e., 7.9647 liters).

Problem: Now, I want to test if I have modeled the pump correctly by setting a different value for the pressure. My understanding is that if I set a fixed value for the pressure in the source element, I would get a lower fluid level in the tank. For instance, if I set the pressure to 0.4 bar, I would expect to get a fluid level of approx. 3.43 liters in the tank when running the simulation for 60 seconds. However, it seems that this is not the case.

In the following model, I have set 0.4 bar as a fixed pressure in the source element:

model M510S_19_MBL

package Medium = Buildings.Media.Water;
  Buildings.Fluid.Movers.SpeedControlled_Nrpm pump1(redeclare package Medium = Medium, redeclare replaceable
      M510S_Data per,
      energyDynamics=Modelica.Fluid.Types.Dynamics.SteadyState,
    y_start=1) annotation(
    Placement(visible = true, transformation(origin = {0, 40}, extent = {{-10, -10}, {10, 10}}, rotation = 0)));
   Modelica.Blocks.Sources.Constant rpm1(k= 10000) "Pump speed control signal"
    annotation (Placement(visible = true, transformation(extent = {{-32, 72}, {-20, 84}}, rotation = 0)));
  Buildings.Fluid.Sources.Boundary_pT source(redeclare package Medium = Medium, nPorts = 1, p = 40000)  annotation(
    Placement(visible = true, transformation(origin = {-60, 40}, extent = {{-10, -10}, {10, 10}}, rotation = 0)));
  Buildings.Fluid.MixingVolumes.MixingVolume tank1(redeclare package Medium = Medium, V = 1, m_flow_nominal = 1, nPorts = 2) annotation(
    Placement(visible = true, transformation(origin = {56, 50}, extent = {{-10, -10}, {10, 10}}, rotation = 0)));
  Buildings.Fluid.Sources.Boundary_pT bou(redeclare package Medium = Medium, nPorts = 1)  annotation(
    Placement(visible = true, transformation(origin = {60, -8}, extent = {{-10, -10}, {10, 10}}, rotation = 0)));
equation
  connect(source.ports[1], pump1.port_a) annotation(
    Line(points = {{-50, 40}, {-10, 40}}, color = {0, 127, 255}));
  connect(rpm1.y, pump1.Nrpm) annotation(
    Line(points = {{-20, 78}, {0, 78}, {0, 52}}, color = {0, 0, 127}));
  connect(pump1.port_b, tank1.ports[1]) annotation(
    Line(points = {{10, 40}, {56, 40}}, color = {0, 127, 255}));
  connect(tank1.ports[2], bou.ports[1]) annotation(
    Line(points = {{56, 40}, {56, 19}, {70, 19}, {70, -8}}, color = {0, 127, 255}));
  annotation(
    uses(Buildings(version = "9.1.0"), Modelica(version = "4.0.0")));
end M510S_19_MBL;

After running the simulation for 60 seconds, tank1.ports[1].m_flow now shows -0.360307 kg/s.

Question: It seems that either my approach to validate the parameters is wrong (e.g., misunderstanding the p-Q diagram) or I am setting the fixed value for pressure in the wrong component. What would be the correct approach for checking the simulated pump behavior under different pressure conditions?

[hcasperfu]

Greetings!
If I understand correctly, you want to see a validation of pressure curve.
Directly serving this purpose, there is a low level validation model Buildings.Fluid.Movers.BaseClasses.Validation.FlowMachineInterface. This one does not directly test the mover but the underlying class that handles the pressure curve.
Once the whole mover model is put in a hydraulic system it becomes more difficult to directly see the pressure-flow curve because of other components playing a role on the pressure.

Your use of the pressure curve looks correct.
A few other comments on your model:

1. If your want to use a straight line as the pressure curve, it is equivalent to using just two points.
2. To see the flow and pressure rise at the pump, you can directly use pump.m_flow and pump.dpMachine, instead of looking at the tank.
3. Buildings.Fluid.Sources.Boundary_pT sets the pressure at a fixed value and Buildings.Fluid.MixingVolumes.MixingVolume has no flow resistance. This then forces the pump to have a pressure rise of bou.p - source.p. And because bou.p has a default value of Medium.p_default which in this case is 3 bars, this forces a back flow at the pump. This is why you see a negative flow rate.

[MatthiasEckhart]

Thank you so much for answering my question and improving my model!

Just a minor follow-up question related to the compatibility of MBL and MSL, and the use of tanks. I am not fully aware what the implications of using Buildings.Fluid.MixingVolumes.MixingVolume are. Due to my lack of knowledge in this area, I would prefer to keep the model as simple as possible and I am therefore considering to use Modelica.Fluid.Vessels.OpenTank instead of the mixing volume. Since I am primarily interested in the fluid level of the tank, I assume that this component is sufficient (and it also provides easy access to this property through level).

I am wondering about potential conflicts that may be caused due to mixing MBL and MSL components. For instance, for the parameterization of Modelica.Fluid.Vessels.OpenTank, I am using Buildings.Media.Water as medium and noticed that the tank seems to inherit a different implicit medium from the system, even though I have not explicitly added Modelica.Fluid.System to the model. As a result, I have to explicitly set the p_ambient parameter of Modelica.Fluid.Vessels.OpenTank to 3 bar to replicate simulation results that are identical to what I had before when using Buildings.Fluid.MixingVolumes.MixingVolume.

To summarize my concerns: Is it okay to incorporate components from both MBL and MSL, given that Buildings.Media.Water does not seem to be fully considered by Modelica.Fluid.Vessels.OpenTank?

Just for reference, my model looks as follows:

model M510S_21_MBL

package Medium = Buildings.Media.Water;
  Buildings.Fluid.Movers.SpeedControlled_Nrpm pump1(redeclare package Medium = Medium, redeclare replaceable
      M510S_Data per,
      energyDynamics=Modelica.Fluid.Types.Dynamics.SteadyState,
    y_start=1) annotation(
    Placement(visible = true, transformation(origin = {0, 40}, extent = {{-10, -10}, {10, 10}}, rotation = 0)));
   Modelica.Blocks.Sources.Constant rpm1(k= 10000) "Pump speed control signal"
    annotation (Placement(visible = true, transformation(extent = {{-32, 72}, {-20, 84}}, rotation = 0)));
  Buildings.Fluid.Sources.Boundary_pT source(redeclare package Medium = Medium, nPorts = 1)  annotation(
    Placement(visible = true, transformation(origin = {-60, 40}, extent = {{-10, -10}, {10, 10}}, rotation = 0)));
  Modelica.Fluid.Vessels.OpenTank tank1(redeclare package Medium = Medium, crossArea = 1, height = 1, level_start = 0, nPorts = 1, portsData = {Modelica.Fluid.Vessels.BaseClasses.VesselPortsData(diameter = 0.006)}, use_portsData = true, p_ambient=300000)  annotation(
    Placement(visible = true, transformation(origin = {60, 46}, extent = {{-20, -20}, {20, 20}}, rotation = 0)));
equation
  connect(source.ports[1], pump1.port_a) annotation(
    Line(points = {{-50, 40}, {-10, 40}}, color = {0, 127, 255}));
  connect(rpm1.y, pump1.Nrpm) annotation(
    Line(points = {{-20, 78}, {0, 78}, {0, 52}}, color = {0, 0, 127}));
  connect(pump1.port_b, tank1.ports[1]) annotation(
    Line(points = {{10, 40}, {60, 40}, {60, 26}}, color = {0, 127, 255}));
  annotation(
    uses(Buildings(version = "9.1.0"), Modelica(version = "4.0.0")));
end M510S_21_MBL;

Setting p_ambient in tank1 to 300000 will produce similar results to what I had before. Without this parameter setting, I get a mass flow rate on port A (i.e., pump1.port_a.m_flow) of 0.497169 kg/s, which will result in the tank being filled with 29.8561 liters (I assume due to the pressure on port B [pump1.port_b.p] being 1.07829 bar).

[hcasperfu]

Greetings!
I'm not aware of any direct conflict mixing components from MBL and MSL.
Modelica.Fluid.System is required whenever you use any component from Modelica.Fluid. If you don't declare it in your code, the tool you use may just add it for you when you run the model (instead of throwing out an error). This is not an issue.
Buildings.Fluid.Water extends from Modelica.Media.Water.ConstantPropertyLiquidWater so they should be compatible as long as you assume the liquid water to be incompressible.
I'm not too familiar with Buildings.Fluid.MixingVolumes.MixingVolume but I believe it has a fixed volume. So if you want to check the fluid level (effectively a variable volume), indeed Modelica.Fluid.Vessels.OpenTank is a better choice.
I would advise that you check your hydraulics first, because needing to set p_ambiant at a certain value doesn't seem right. It looks like the pump is stuck between two fixed (constant) pressures and is not actually doing anything. Maybe adding a flow resistance next to the pump can better represent the system.

[MatthiasEckhart]

Hi @hcasperfu,
thanks a lot for your comprehensive feedback! I really appreciate your help.

[hcasperfu]

Greetings!
As a followup, there will be a new validation model Buildings.Fluid.Movers.Validation.PressureCurve that outputs the pressure curve from the mover model. Simply plot mov.dpMachine vs mov.VMachine_flow.
This is already available on the master branch (368f3a3 or later).

Cheers,
Casper