How to write a show implementation for a custom type? (aka shadowed binding)

[tom-sherman]

I have a type and I'm trying to write a show implementation for it:

type json
  JSONFalse
  JSONTrue
  JSONNull
  JSONNumber(value: float64)
  JSONString(value: string)
  JSONArray(value: list<json>)
  JSONObject(value: list<(string, json)>)

fun show(json: json)
  match json
    JSONFalse -> "False"
    JSONTrue -> "True"
    JSONNull -> "Null"
    JSONString(value) -> "\"" ++ value ++ "\""
    JSONNumber(value) -> value.show // Type error here

However the last line gets me a type error:

json.kk(17,35): error: types do not match
  context      :                                   value.show
  term         :                                   value
  inferred type: float64
  expected type: json

I've come across this error of shadowed binding a few times now, how can I get around it?

[tom-sherman]

So the problem is that show actually isn't defined for float64. I instead need to call show-fixed like:

match json
    JSONNumber(value) -> value.show-fixed

The error from the compiler was mostly a red herring.

My implementation ended up like this:

fun show(json: json) : <div|_e> string
  match json
    JSONFalse -> "False"
    JSONTrue -> "True"
    JSONNull -> "Null"
    JSONString(value) -> "\"" ++ value ++ "\""
    JSONNumber(value) -> value.show-fixed
    JSONArray(value) -> value.show-list(show)

[tom-sherman]

I think I'm still stuck on the shadowing problem though. I think this is related to #177

[mwchase]

Wait, isn't there https://koka-lang.github.io/koka/doc/std_core-source.html#show_1?

[tom-sherman]

Hmm, not sure why that wasn't working for me 🤔

I've published the code so please let me know if you can spot anything obvious, I'll try to take another look also

https://github.com/tom-sherman/koka-json/blob/b4e9bc7801dff9729cd1312040b046f0f4246c77/json.kk

[mwchase]

Okay, I did a bunch of stuff, so I don't know if this will work, but try putting the show calls back, and changing the function declaration to fun show(json: json) : pure string. That seemed to make everything suddenly work for me. I cloned your repo (which already has the annotation, of course) and changed the end of the file to

pub fun show(json: json) : pure string
  match json
    JSONFalse -> "false"
    JSONTrue -> "true"
    JSONNull -> "null"
    JSONString(value) -> "\"" ++ value ++ "\""
    JSONNumber(value) -> value.show
    JSONArray(value) -> value.show-list(show)
    JSONObject(kvs) -> "{" ++ kvs.map(fn((k, v)) "\"" ++ k ++ "\":" ++ show(v)).join(",") ++ "}"

pub val stringify : json -> pure string = show

And the tests passed.

So it's literally just type inference getting confused, and typical annotations will bail it out apparently.

[tom-sherman]

🤔 That's obvious now, I'm sure I was getting inference ambiguity inside of the show function though. Maybe I needed more coffee at the time.

Thanks so much!