While it can hypothetically be worked around with scripting, it would require a large amount of script, and you would always be losing access to the automatic word shaping, an easy-to-use label, or a number of other features that make the RichTextLabel excellent for dialogue.

You did mention RichTextEffect. CharFXTransform even contains elapsed_time which allows you to have full control on the way the character is displayed, specifically at the beginning. This transition is not something identical for every game, so the extra customization is important.
A bit of fading isn't exactly a "large" amount of scripting, it can be probably clumped up to a formula.

So, a system for this already exists. What's the drawback of the current system?

While it can hypothetically be worked around with scripting, it would require a large amount of script, and you would always be losing access to the automatic word shaping, an easy-to-use label, or a number of other features that make the RichTextLabel excellent for dialogue.

You did mention RichTextEffect. CharFXTransform even contains elapsed_time which allows you to have full control on the way the character is displayed, specifically at the beginning. This transition is not something identical for every game, so the extra customization is important. A bit of fading isn't exactly a "large" amount of scripting, it can be probably clumped up to a formula.

So, a system for this already exists. What's the drawback of the current system?

Elapsed time doesn't act like it says it does, though.

It's not elapsed time per character, it's time elapsed for the entire label since the text was set. This is... a bit of a roadblock to having it done cleanly.

Well, if you are controlling how fast the text appears, calculating time needed to reach a character shouldn't be a problem.

If the text is displayed at a variable rate, however, that becomes a lot more difficult. With the current system you can only have certain properties at any given time.

Precalculated timing doesn't work when, say, you have dialogue that can be advanced earlier than it would normally finish by the player hitting "continue", which is generally standard in games with dialogue these days.

If it is something like this:

Then it's possible to do it with scripts. It's not straightforward but doable.

RichTextEffect script:

@tool
class_name FlyRichTextEffect
extends RichTextEffect


var bbcode = "fly"
var data = {}
var delta:float = 0.0
var visible_characters:int = -1:
	set(new_value):
		visible_characters = new_value
		# Clean up the data if we are showing less characters than before
		if visible_characters < 0:
			data.clear()
		else:
			for data_range in data.keys():
				if data_range.x > visible_characters:
					data.erase(data_range)


func _process_custom_fx(char_fx: CharFXTransform) -> bool:
	if visible_characters < 0:
		return true

	var starting_x = float(char_fx.env.get('start', -10))
	var speed = float(char_fx.env.get('speed', 50))

	var range = char_fx.range

	# get the char data, set the default data if not available
	var char_data = data.get(range, {
		"offset_x": starting_x,
		"end": char_fx.transform,
		"finished": false
	})

	var finished = char_data.get("finished", false)

	# if not finished then update the offset_x until it reaches 0
	# update the char_fx values with that
	if not finished:
		var offset_x = char_data.get('offset_x', starting_x)
		offset_x = move_toward(offset_x, 0, delta * speed)
		if offset_x >= 0:
			offset_x = 0
			char_data['finished'] = true

		char_fx.offset.x = floor(offset_x)
		char_fx.color.a = remap(offset_x, starting_x, 0, 0.0, 1.0)

		char_data['offset_x'] = offset_x

	# update the data dictionary
	data[range] = char_data

	return true

RichTextLabelScript script:

@tool
extends RichTextLabel

var fly_effect:FlyRichTextEffect

func _ready() -> void:
	# Disable clip contents or the first glyph of each line will be clipped from the left
	clip_contents = false

	fly_effect = FlyRichTextEffect.new()
	custom_effects.clear()
	install_effect(fly_effect)

func _process(delta: float) -> void:
	fly_effect.delta = delta
	fly_effect.visible_characters = visible_characters

You can get an idea on how to get whatever effect you are after. Basically, maintain a dictionary with glyph ranges as keys and the data you want to update as values. When changing the RichTextLabel.visible_characters value, it will remove old glyph values that have a range larger than the visible characters' value. And for each glyph within the visible characters' range that is not already in the dictionary with starting values, create a new entry in the dictionary and update its values.

If you need more control with how the visible characters animate in and out don't use RichTextLabel.visible_characters and use a custom variable. Animate whatever you need and set the alpha of the characters that should be hidden to 0.

Ah, so it is actually possible with not too much code, it's just... awkward and very unintuitive. I think that adding a tutorial for this effect (or something like this) to the docs, as I'm sure many developers would love to know that this is something you can do, as well as how to do it. As @mrcdk seems to know how it works, I think that he could be a good candidate for writing this tutorial. However, if I could get some direction from some of the more experienced Docs users, I could attempt to write this myself.

I edited the above comment to use GDScript syntax highlighting, in case users are to stumble over this proposal.

I was looking to add the same feature for my game in a less hacky way, so I opened a pull request for a simple, built-in method.