Is it possible to explicitly inherit completions for a git alias?

[jaminthorns]

I have an issue relating to command completion inheritance with git aliases, and I'm not quite sure how to solve it or whether it's even possible. I have a fish function I've written that essentially acts like a fzf-enhanced version of git diff:

function _git_compare --wraps 'git diff'
    # ...
end

When calling this function directly, I get the inherited completions from git diff, as expected. Thing is, I don't want to call this function directly, I want it as a git alias, so I've added it to my .gitconfig like this:

[alias]
	compare = ! fish -c '_git_compare $argv' --

This works well, except for the fact that fish loses the command completions from git diff. This is totally understandable, I wouldn't expect fish to parse the content of a command that I'm passing to a fish shell in a git alias, that seems like a terribly complex thing to do programmatically.

What I figured I could do is explicitly tell fish with the complete command how I'd like my git compare alias to inherit completions:

complete -c git -w _git_compare -n '__fish_git_using_command compare'
complete -c git -w 'git diff' -n '__fish_git_using_command compare'

But neither of those seem to work. Is there any way I can inherit command completions from git show for my git compare alias?

[faho]

See #5412. The git completions specifically allow this:

set -g __fish_git_alias_compare diff

[jaminthorns]

This totally works, thank @faho! I had read through the code that generates the __fish_git_alias_ variables and the code that checks those variables, but didn't put two and two together to realize I could override those variables myself.

There is a pretty big gotcha in doing this, though. Since fish loads completions on-demand, the code that generates the __fish_git_alias_ variables runs only once I've attempted to tab-complete the git command. This means that I can't just add set -g __fish_git_alias_compare diff to my config.fish file or a conf.d script (though it works fine after the completions have been loaded). To get this to work with typical usage, I've had to do the following:

• In my config.fish, manually run the shipped git completions and set the __fish_git_alias_compare variable:

  source /usr/local/opt/fish/share/fish/completions/git.fish
  set -g __fish_git_alias_compare diff

• Create an empty git.fish file in my completions folder to override the auto-loading of the shipped git completions.

This has the drawback that the git completions are now run at shell startup instead of being autoloaded. This takes my shell startup time (measured with time fish --interactive -c "") from ~25 ms to ~70 ms. I've done a decent bit of work to optimize my shell startup time, so this is a bit disappointing.

Is there any way I can trigger the overriding of __fish_git_alias_ variables immediately after the git completion script runs? The only global variables defined in share/completions/git.fish are the __fish_git_alias_ variables themselves, and using them with function --on-variable inevitably leads to infinite loops (since I'd be setting the variable I'm listening on).

[jaminthorns]

Oops, I just realized you addressed my problem in the issue you linked 🤦‍♂️:

Just copy the default completions (in e.g. /usr/local/share/fish/completions/) there and make your changes.

Even still, I'd prefer not to have to keep a local modification of share/completions/git.fish, though I realize I could automate this by writing a script to copy the file and append the extra logic to the end. Regardless, soon after typing up that big reply, I came up with an alternative solution that doesn't involve copying and modifying share/completions/git.fish. Using this function:

function _override_git_alias_completion -a alias command
    set variable __fish_git_alias_$alias

    function _override_git_alias_completion_$alias -V command -V variable -v $variable
        if not test $$variable = $command
            set -g $variable $command
        end
    end
end

We can override a __fish_git_alias_ variable immediately after it's defined with a simple value check to avoid infinite loops. I've got this function defined in a conf.d script with my overrides directly below:

_override_git_alias_completion view show
_override_git_alias_completion compare diff
_override_git_alias_completion history log
_override_git_alias_completion stashes stash
_override_git_alias_completion branches branch

And it works great! No need for circumventing the autoloading of the git completions (like in my previous reply) or copying/modifying the git completions file.

[krobelus]

On Thu, Mar 24, 2022 at 08:56:07AM -0700, Jamin Thornsberry wrote:

I have an issue relating to command completion inheritance with git aliases, and I'm not quite sure how to solve it or whether it's even possible. I have a fish function I've written that essentially acts like a fzf-enhanced version of git diff:

function _git_compare --wraps 'git diff'
    # ...
end

When calling this function directly, I get the inherited completions from git diff, as expected. Thing is, I don't want to call this function directly, I want it as a git alias, so I've added it to my .gitconfig like this:

[alias]
	compare = ! fish -c '_git_compare $argv' --

why don't you make it a script called git-compare?
Then you don't need a shell alias, and running
complete git-compare --wraps 'git diff'
is enough to get custom completions, also for git compare (might need to
restart your shell because we enumerate all possible git-foo commands only
when loading git completions).

This works well, except for the fact that `fish` loses the command completions from `git diff`. This is totally understandable, I wouldn't expect `fish` to parse the content of a command that I'm passing to a `fish` shell in a `git` alias, that seems like a terribly complex thing to do programmatically.

What I figured I could do is explicitly tell `fish` with the `complete` command how I'd like my `git compare` alias to inherit completions:

```fish
complete -c git -w _git_compare -n '__fish_git_using_command compare'
complete -c git -w 'git diff' -n '__fish_git_using_command compare'

These don't do what you expect. fish reads each of those lines as two independent completions:

$ complete git -w 'git diff' -n '__fish_git_using_command compare'
$ complete git
complete git -n '__fish_git_using_command compare'
complete git --wraps 'git diff'

maybe this should be an error

But neither of those seem to work. Is there any way I can inherit command completions from `git show` for my `git compare` alias?

BTW, a more realistic feature we should support are multi-level aliases:

[alias]
	a = b
	b = diff

completion for git a works with bash's git completions but not with ours

[jaminthorns]

I only looked into this after going in-depth with @faho's answer, but this works great too! In fact, this is probably better for my use case than using aliases. If I could, I'd mark this as an answer as well. I'm only keeping @faho's marked because his more directly addresses the completion of aliases.

I actually had no idea about this functionality before looking into your answer. The only place this seems to be officially documented is in the documentation for the --list-cmds flag:

List commands by group. This is an internal/experimental option and may change or be removed in the future. Supported groups are: builtins, parseopt (builtin commands that use parse-options), main (all commands in libexec directory), others (all other commands in $PATH that have git- prefix), list- (see categories in command-list.txt), nohelpers (exclude helper commands), alias and config (retrieve command list from config variable completion.commands)

Though it seems to be common knowledge, since searching "custom git commands" gives me plenty of articles written over the years:

• Custom Git Commands in 3 Steps
• Automate repetitive tasks with custom git commands
• How to write your own git commands like "git refresh"?
• Write and maintain custom git commands

There does seem to be a serious performance impact, though. I actually have 5 of these custom git commands (and might add more in the future). It seems that for each command I add completions for with complete, like this:

complete -c git-compare -w 'git diff'

The execution time of the first git completion (AKA the execution of share/completions/git.fish) slows down by about ~100 ms (measured with time complete -C 'git ' immediately after shell startup). This means that the first time I try to autocomplate git in a shell is noticeably slower (~500 ms) with these completions. I'm guessing the performance decrease comes from this usage of complete -C. Should I report this as an issue, or is this expected?

[krobelus]

wow thanks for reporting. There's definitely a big performance problem here if the user predefines wrappers like complete -c git-compare -w 'git diff'. I'll try to come up with a fix

[krobelus]

the slowness should be fixed as of ff72e3f, let's see how this goes

[jaminthorns]

I copied the latest version of share/completions/git.fish to my local completions folder, and it definitely seems to be fixed! Thanks so much, @krobelus! 😁

[krobelus]

On Thu, Mar 24, 2022 at 08:56:07AM -0700, Jamin Thornsberry wrote: I have an issue relating to command completion inheritance with `git` aliases, and I'm not quite sure how to solve it or whether it's even possible. I have a `fish` function I've written that essentially acts like a `fzf`-enhanced version of `git diff`: ```fish function _git_compare --wraps 'git diff' # ... end ``` When calling this function directly, I get the inherited completions from `git diff`, as expected. Thing is, I don't want to call this function directly, I want it as a `git` alias, so I've added it to my `.gitconfig` like this: ```ini [alias] compare = ! fish -c '_git_compare $argv' --

why don't you make it a script called `git-compare`? Then you don't need the alias and running `complete git-compare --wraps 'git diff'` is enough to get custom completions, also for `git compare` (might need to restart your shell because we enumerate all possible git-foo commands only when loading git completions).

``` This works well, except for the fact that `fish` loses the command completions from `git diff`. This is totally understandable, I wouldn't expect `fish` to parse the content of a command that I'm passing to a `fish` shell in a `git` alias, that seems like a terribly complex thing to do programmatically. What I figured I could do is explicitly tell `fish` with the `complete` command how I'd like my `git compare` alias to inherit completions: ```fish complete -c git -w _git_compare -n '__fish_git_using_command compare' complete -c git -w 'git diff' -n '__fish_git_using_command compare'

These don't do what you expect. Fish reads each of those lines as two independent completions: $ complete git -w 'git diff' -n '__fish_git_using_command compare' $ complete git complete git -n '__fish_git_using_command compare' complete git --wraps 'git diff' maybe this should be an error

``` But neither of those seem to work. Is there any way I can inherit command completions from `git show` for my `git compare` alias?

BTW, a more realistic feature we should support are multi-level aliases: [alias] a = b b = diff completion for `git a` works with bash's git completions but not with ours