(defvar auto-rename-tag--after-change-active nil)

(defun auto-rename-tag--before-change-functions (_begin _end)
  "Do stuff before buffer is changed.
BEGIN : beginning of the changes.
END : end of the changes."
  (unless auto-rename-tag--after-change-active

    ;; Reset record.
    (setq auto-rename-tag--record-prev-word "")
    ;; Reset flag.
    (setq auto-rename-tag--pre-command-actived nil)

    (when (and (not undo-in-progress)
               (auto-rename-tag--inside-tag-p)
               (not (auto-rename-tag--self-tag-p)))
      (save-excursion
        ;; Set active flag.
        (setq auto-rename-tag--pre-command-actived t)

        (setq auto-rename-tag--record-prev-word (auto-rename-tag--get-tag-name-at-point))

        (when (string= auto-rename-tag--record-prev-word "/")
          (setq auto-rename-tag--record-prev-word ""))

        ;; Ensure `auto-rename-tag--record-prev-word' is something other than nil.
        (unless auto-rename-tag--record-prev-word
          (setq auto-rename-tag--record-prev-word ""))))))

(defun auto-rename-tag--after-change-function (_begin _end _length)
  "Do stuff after buffer is changed.
BEGIN : beginning of the changes.
END : end of the changes.
LENGTH : deletion length."
  (when auto-rename-tag--pre-command-actived
    (run-at-time 0 nil (lambda () 
                         (save-excursion
                           (let ((is-end-tag nil)
                                 (current-word "") (pair-tag-word "")
                                 (auto-rename-tag--after-change-active nil))
                             ;; Goto the first character inside the tag.
                             (auto-rename-tag--goto-the-start-of-tag-name)

                             (setq is-end-tag (auto-rename-tag--is-closing-tag-p))

                             (setq current-word (auto-rename-tag--get-tag-name-at-point))

                             (unless (string= current-word auto-rename-tag--record-prev-word)
                               ;; NOTE: Is closing tag.
                               (when is-end-tag
                                 (auto-rename-tag--resolve-nested 'backward)

                                 ;; Get the tag name and ready to be compare.
                                 (setq pair-tag-word (auto-rename-tag--get-tag-name-at-point))

                                 ;; Ensure `pair-tag-word' is something other than nil.
                                 (unless pair-tag-word (setq pair-tag-word ""))

                                 (when (string= auto-rename-tag--record-prev-word pair-tag-word)
                                   ;; Delete the pair word.
                                   (unless (string= pair-tag-word "")
                                     (auto-rename-tag--delete-tag-name))
                                   ;; Insert new word.
                                   (insert current-word)))

                               ;; NOTE: Is opening tag.
                               (unless is-end-tag
                                 (auto-rename-tag--resolve-nested 'forward)

                                 (setq is-end-tag (auto-rename-tag--is-closing-tag-p))

                                 ;; Get the tag name and ready to be compare.
                                 (setq pair-tag-word (auto-rename-tag--get-tag-name-at-point))

                                 ;; Ensure `pair-tag-word' is something other than nil.
                                 (unless pair-tag-word (setq pair-tag-word ""))

                                 (when (string= auto-rename-tag--record-prev-word pair-tag-word)
                                   ;; Delete the pair word.
                                   (unless (string= pair-tag-word "")
                                     (auto-rename-tag--delete-tag-name))
                                   ;; Insert new word.
                                   (insert current-word))))))))))