-
Notifications
You must be signed in to change notification settings - Fork 0
/
Tokeniser.x
155 lines (134 loc) · 3.58 KB
/
Tokeniser.x
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
--
-- This file is part of FactorCSS
-- Licensed under the MIT License,
-- http://www.opensource.org/licenses/mit-license
-- Copyright 2005 James Bursa <[email protected]>
--
-- Tokeniser for CSS 2.1
-- See CSS 2.1 G.2
{
module Tokeniser where
}
%wrapper "posn"
$h = [0-9a-f]
$nonascii = [\x80-\xff]
@unicode = \\$h{1,6}(\r\n|[\ \t\r\n\f])?
@escape = @unicode|\\[\x20-\x7e\x80-\xff]
@nmstart = [_a-zA-Z]|$nonascii|@escape
@nmchar = [\-_a-zA-Z0-9]|$nonascii|@escape
@nl = \n|\r\n|\r|\f
@string1 = \"([\t\ \!\#\x24\x25&\x28-\x7e]|\\@nl|\'|$nonascii|@escape|\.)*\"
@string2 = \'([\t\ \!\#\x24\x25&\x28-\x7e]|\\@nl|\"|$nonascii|@escape|\.)*\'
@ident = @nmstart@nmchar*
@name = @nmchar+
@num = [\-\053]?([0-9]+|[0-9]*"."[0-9]+)
@string = @string1|@string2
@url = ([\!\#\x24\x25&\x2a-\x7e]|$nonascii|@escape)*
$s = [\ \t\r\n\f]
@w = $s*
@range = \?{1,6}|$h(\?{0,5}|$h(\?{0,4}|$h(\?{0,3}|$h(\?{0,2}|$h(\??|$h)))))
$all = \x00-\xff
@comment = \/\*$all#\x2a*\*+($all#[\/\x2a]$all#\x2a*\*+)*\/
tokens :-
$s+ { \p s -> (S, p) }
@comment ;
"<!--" ;
"-->" ;
"~=" { \p s -> (INCLUDES, p) }
"|=" { \p s -> (DASHMATCH, p) }
@w"{" { \p s -> (LBRACE, p) }
@w"}" { \p s -> (RBRACE, p) }
@w"+" { \p s -> (PLUS, p) }
@w">" { \p s -> (GREATER, p) }
@w"," { \p s -> (COMMA, p) }
@string { \p s -> (STRING s, p) }
@ident { \p s -> (IDENT s, p) }
"#"@name { \p s -> (HASH s, p) }
"@import" { \p s -> (IMPORT_SYM, p) }
"@page" { \p s -> (PAGE_SYM, p) }
"@media" { \p s -> (MEDIA_SYM, p) }
"@charset" { \p s -> (CHARSET_SYM, p) }
"!"@w"important" { \p s -> (IMPORTANT_SYM, p) }
@num em { \p s -> (EMS (readz (take (length s - 2) s) p), p) }
@num ex { \p s -> (EXS (readz (take (length s - 2) s) p), p) }
@num px { \p s -> (LENGTH s, p) }
@num cm { \p s -> (LENGTH s, p) }
@num mm { \p s -> (LENGTH s, p) }
@num in { \p s -> (LENGTH s, p) }
@num pt { \p s -> (LENGTH s, p) }
@num pc { \p s -> (LENGTH s, p) }
@num deg { \p s -> (ANGLE s, p) }
@num rad { \p s -> (ANGLE s, p) }
@num grad { \p s -> (ANGLE s, p) }
@num ms { \p s -> (TIME s, p) }
@num s { \p s -> (TIME s, p) }
@num Hz { \p s -> (FREQ s, p) }
@num kHz { \p s -> (FREQ s, p) }
@num @ident { \p s -> (DIMEN s, p) }
@num "%" { \p s -> (PERCENTAGE (readz (take (length s - 1) s) p), p) }
@num { \p s -> (NUMBER (readz s p), p) }
"url("@w@string@w")" { \p s -> (URI s, p) }
"url("@w@url@w")" { \p s -> (URI s, p) }
@ident"(" { \p s -> (FUNCTION s, p) }
";" { \p s -> (SEMI, p) }
":" { \p s -> (COLON, p) }
"/" { \p s -> (SLASH, p) }
"-" { \p s -> (MINUS, p) }
"." { \p s -> (DOT, p) }
"*" { \p s -> (ASTERISK, p) }
"[" { \p s -> (LBRAC, p) }
"]" { \p s -> (RBRAC, p) }
"=" { \p s -> (EQUALS, p) }
")" { \p s -> (RPAREN, p) }
. { \p s -> (DELIM (head s), p) }
{
type TokenPosn = (Token, AlexPosn)
data Token =
S |
INCLUDES |
DASHMATCH |
LBRACE |
PLUS |
GREATER |
COMMA |
STRING String |
IDENT String |
HASH String |
IMPORT_SYM |
PAGE_SYM |
MEDIA_SYM |
CHARSET_SYM |
IMPORTANT_SYM |
EMS Float |
EXS Float |
LENGTH String |
ANGLE String |
TIME String |
FREQ String |
DIMEN String |
PERCENTAGE Float |
NUMBER Float |
URI String |
FUNCTION String |
SEMI |
RBRACE |
COLON |
SLASH |
MINUS |
DOT |
ASTERISK |
LBRAC |
RBRAC |
EQUALS |
RPAREN |
DELIM Char
deriving (Eq, Show)
readz :: Read a => String -> AlexPosn -> a
readz s (AlexPn _ l c) =
if (null xs) || not (null (snd (head xs)))
then error ("Parse error at " ++ "line " ++ show l ++
", column " ++ show c ++
" (when parsing \"" ++ s ++ "\")")
else fst (head xs)
where xs = reads s
}